Difference between revisions of "Manuscript Details"

Revision as of 15:20, 10 June 2011

Query 1: Show proteins that are downregulated in the epimastigote stage and exist in a single metabolic pathway.

SPARQL Query:

PREFIX BASE: <http://knoesis.wright.edu/ParasiteExperiment.owl#>
PREFIX PATHWAY: <http://purl.org/obo/owlapi/pathway#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX so: <http://purl.org/obo/owl/sequence#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX NCI: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>

SELECT ?gene ?microarray ?pathwaylabel ?logbasevalue ?entry ?pathway
FROM <http://knoesis.wright.edu/tcruzi4>
WHERE { GRAPH <http://knoesis.wright.edu/tcruzi4>
{
?microarray BASE:has_output_value ?gene .
?microarray BASE:has_output_value ?logbase .
?microarray rdf:type NCI:Microarray_Analysis .
?logbase rdf:type BASE:log_base2_ratio .
?logbase BASE:has_value ?logbasevalue .
?gene rdf:type so:gene .
?entry owl:sameAs ?gene .
?entry rdf:type so:gene .
?entry BASE:involved_in ?pathway .
?pathway rdf:type BASE:pathway .
?pathway rdfs:label ?pathwaylabel
FILTER regex(?microarray , "epimastigote") .
FILTER (?logbasevalue < -1) .
{
	SELECT  ?gene count(?pathway)
	FROM <http://knoesis.wright.edu/tcruzi4>
	WHERE { GRAPH <http://knoesis.wright.edu/tcruzi4>
	{
	?microarray BASE:has_output_value ?gene .
           ?microarray rdf:type NCI:Microarray_Analysis .
	?gene rdf:type so:gene .
	?entry owl:sameAs ?gene .
	?entry rdf:type so:gene .
	?entry BASE:involved_in ?pathway .
	?pathway rdf:type BASE:pathway .
	?pathway rdfs:label ?pathwaylabel
	FILTER regex(?microarray , "epimastigote") .
	}
	}
	group by ?gene
	having count(?pathway) = 1
	}
}
}

Query 2: Give the gene knockout summaries, both for plasmid construction and strain creation, for all gene knockout targets that are 2-fold upregulated in amastigotes at the transcript level and that have orthologs in Leishmania but not in Trypanosoma brucei.

Cuebee Query:
Query 2 Download Link

SPARQL Query:

PREFIX BASE: <http://knoesis.wright.edu/ParasiteExperiment.owl#>
PREFIX PATHWAY: <http://purl.org/obo/owlapi/pathway#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX so: <http://purl.org/obo/owl/sequence#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX NCI: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
PREFIX provenir: <http://knoesis.wright.edu/provenir/provenir.owl#>
PREFIX ro: <http://obofoundry.org/ro/ro.owl#>
PREFIX PLO: <http://paige.ctegd.uga.edu/ParasiteLifecycle.owl#>

SELECT DISTINCT ?gene ?KOStatus ?KOLog ?knockoutProject ?StrainID  ?StrainStatusURL ?strainSummary
FROM <http://knoesis.wright.edu/tcruzi4>
WHERE { GRAPH <http://knoesis.wright.edu/tcruzi4>
{
?knockout provenir:has_parameter ?gene .
?knockout ro:part_of ?knockoutProject .
?knockoutProject rdf:type BASE:knockout_project_protocol .
?gene rdf:type so:gene .
?StrainID provenir:has_parameter ?gene .
?StrainID rdf:type BASE:strain_creation_protocol .
?knockoutProject provenir:has_parameter ?Log .
?Log rdf:type BASE:KOlog .
?Log rdfs:label ?KOLog .
?knockoutProject provenir:has_parameter ?StatusURL .
?StatusURL rdf:type BASE:status .
?StatusURL rdfs:label ?KOStatus .
?microarray BASE:has_output_value ?logbase .
?microarray rdf:type NCI:Microarray_Analysis .
?microarray BASE:has_output_value ?gene .
?logbase rdf:type BASE:log_base2_ratio .
?logbase BASE:has_value ?log2ratio .
?gene BASE:is_orthologous_to ?ortholog .
?ortholog rdf:type so:gene .
?ortholog ro:derives_from ?x .
?x rdf:type PLO:organism .
FILTER regex(?x, "LMA") .
FILTER regex(?microarray, "amastigote") .
FILTER (?log2ratio > 1) .
 OPTIONAL
{?StrainID provenir:has_parameter ?StrainStatusURL .
 ?StrainStatusURL rdf:type BASE:status. }
OPTIONAL { ?StrainID provenir:has_parameter ?StrainSummaryURL .
 ?StrainSummaryURL rdf:type BASE:strain_summary.
 ?StrainSummaryURL rdfs:label ?strainSummary .
}
}
}

Query 3: Give the strain summary for all strains created through single or double knockout of a protein kinase gene.

Cuebee Query:
Query 3 Download Link

SPARQL Query:

PREFIX BASE: <http://knoesis.wright.edu/ParasiteExperiment.owl#>
PREFIX PATHWAY: <http://purl.org/obo/owlapi/pathway#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX so: <http://purl.org/obo/owl/sequence#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX NCI: <http://ncicb.nci.nih.gov/xml/owl/EVS/Thesaurus.owl#>
PREFIX provenir: <http://knoesis.wright.edu/provenir/provenir.owl#>
PREFIX ro: <http://obofoundry.org/ro/ro.owl#>

SELECT DISTINCT ?StrainID ?strainSummary
WHERE { GRAPH <http://knoesis.wright.edu/tcruzi4>
{
?gene BASE:has_GO_annotation ?go_term .
?go_term rdfs:label ?GOtermLable .
?gene rdf:type so:gene .
?go_term rdf:type BASE:GO_term .
FILTER regex(?GOtermLable, "kinase") .
FILTER regex(?GOtermLable, "protein") .
?StrainID provenir:has_parameter ?gene .
?StrainID rdf:type BASE:strain_creation_protocol .
?StrainID provenir:has_parameter ?StrainSummaryURL .
?StrainSummaryURL rdf:type BASE:strain_summary.
?StrainSummaryURL rdfs:label ?strainSummary .
}
}

@@ Line 70: / Line 70: @@
 Cuebee Query: <br />
 [http://jade.cs.uga.edu:8080/download/query2.html Query 2]
+[http://jade.cs.uga.edu:8080/download/query2.avi Download Link]
 SPARQL Query:
@@ Line 131: / Line 132: @@
 Cuebee Query: <br />
 [http://jade.cs.uga.edu:8080/download/query3.html Query 3]
+[http://jade.cs.uga.edu:8080/download/query3.avi Download Link]
 SPARQL Query:

Difference between revisions of "Manuscript Details"

Revision as of 15:20, 10 June 2011

Navigation menu

Views

Personal tools

Navigation

Homepage

Search

Tools